!!! Plošný model struktury A o rozměru NxN buněk !!!

FINISH
/CLEAR

*ABBR,INPUT,'/INPUT,strukturaA_NxN,txt'    


!!!!!!!!!!!!!!!!!!!
!!! PREPROCESOR !!!
!!!!!!!!!!!!!!!!!!!

/PREP7

*AFUN,RAD            
 PI=4*ATAN(1)        
*AFUN,DEG            

!!! Vstupni parametry !!!
H=10			! delka H [mm]
LH=1.25			! pomer L/H [mm]
alfa=60			! uhel alfa [deg]
T=1				! tloustka [mm]
Emod=200000		! modul pruznosti v tahu zakladniho materialu [MPa]
nu=0.3			! Poissonuv pomer zakladniho materialu [-]
Fappl=1			! zatezna sila [N]
ELSIZE=0.5		! velikost prvku [mm]
N=5				! pocet bunek ve svislem i vodorovnem smeru [-]


L=LH*H
TH=1

!!! Definice elementu !!!
ET,1,PLANE183

!!! Definice materialu !!!
MP,EX,1,Emod
MP,PRXY,1,,nu

!!! Tvorba geometrie !!!

	!!!Referencni geometrie !!!
!K,111,H-L*cos(alfa),0,0
!K,222,H,L*sin(alfa),0
!K,333,-H,L*sin(alfa),0
!K,444,-H+L*cos(alfa),0,0
!K,555,-H,-L*sin(alfa),0
!K,666,H,-L*sin(alfa),0
!K,777,2*H-L*cos(alfa),0,0
!K,888,-2*H+L*cos(alfa),0,0

!L,111,222	$	L,222,333	$	L,333,444	$	L,444,555	$	L,555,666	$	L,666,111	$	L,111,777	$	L,444,888

	!!! Vnitrni geometrie !!!
K,1,H-L*cos(alfa)-T/(2*cos(90-alfa)),0,0
K,2,H-T/2*(cos(alfa/2)/sin(alfa/2)),L*sin(alfa)-T/2,0
K,3,-H+T/2*(cos(alfa/2)/sin(alfa/2)),L*sin(alfa)-T/2,0
K,4,-H+L*cos(alfa)+T/(2*cos(90-alfa)),0,0
K,5,-H+T/2*(cos(alfa/2)/sin(alfa/2)),-L*sin(alfa)+T/2,0
K,6,H-T/2*(cos(alfa/2)/sin(alfa/2)),-L*sin(alfa)+T/2,0

L,1,2	$	L,2,3	$	L,3,4	$	L,4,5	$	L,5,6	$	L,6,1	$	!L,1,7	$	L,4,8

	!!! Vnejsi geometrie !!!
K,11,H-L*cos(alfa)+T/(2*tan(alfa/2)),T/2,0
K,22,H+T/2*(cos(alfa/2)/sin(alfa/2))-T/2*tan(90-alfa),L*sin(alfa),0
K,33,-H-T/2*(cos(alfa/2)/sin(alfa/2))+T/2*tan(90-alfa),L*sin(alfa),0
K,41,-H+L*cos(alfa)-T/(2*tan(alfa/2)),T/2,0
K,81,-2*H+L*cos(alfa),T/2,0
K,82,-2*H+L*cos(alfa),-T/2,0
K,42,-H+L*cos(alfa)-T/(2*tan(alfa/2)),-T/2,0
K,55,-H-T/2*(cos(alfa/2)/sin(alfa/2))+T/2*tan(90-alfa),-L*sin(alfa),0
K,66,H+T/2*(cos(alfa/2)/sin(alfa/2))-T/2*tan(90-alfa),-L*sin(alfa),0
K,12,H-L*cos(alfa)+T/(2*tan(alfa/2)),-T/2,0
K,71,2*H-L*cos(alfa),-T/2,0
K,72,2*H-L*cos(alfa),T/2,0

L,11,22	$	L,33,41	$	L,41,81	$	L,81,82	$	L,82,42	$	L,42,55	$	L,66,12	$	L,12,71	$	L,71,72	$	L,72,11	$	L,22,33	$	L,55,66

!!! Vytvoreni struktury !!!
	
	!!! Zakladni struktura !!!
LSEL,ALL
AL,ALL

ASEL,ALL
AGEN,N,ALL,,,2*(2*H-L*cos(alfa)),0,0,,0

ASEL,ALL
AGEN,N,ALL,,,0,2*L*sin(alfa),0,,0

!!! Vytvoreni site !!!
ASEL,ALL
ESIZE,ELSIZE
AATT,1,,1
AMESH,ALL

NUMMRG,NODE,0.000001
NUMMRG,KP,0.000001

!!! Okrajove podminky !!!
NSEL,S,LOC,Y,(2*N-1)*L*sin(alfa)			$	CP,1,UY,ALL			
NSEL,S,LOC,Y,-L*sin(alfa)					$	D,ALL,UY,0	
NSEL,S,LOC,X,-2*H+L*cos(alfa)				$	D,ALL,UX,0
NSEL,S,LOC,X,(2*N-1)*(2*H-L*cos(alfa))		$	CP,2,UX,ALL

ALLSEL,ALL

!!! Zatizeni !!!
NSEL,S,LOC,Y,(2*N-1)*L*sin(alfa)	$	NSEL,R,LOC,X,0
F,ALL,FY,-Fappl

ALLSEL,ALL


!!!!!!!!!!!!!!!!
!!! SOLUTION !!!
!!!!!!!!!!!!!!!!
	
/SOLU

SOLVE


!!!!!!!!!!!!!!!!!!!!!
!!! POSTPROCESSOR !!!
!!!!!!!!!!!!!!!!!!!!!

SELTOL,1e-6

!!! Zjisteni posuvu ve smeru x !!!
NSEL,S,LOC,X,-2*H+L*cos(alfa)	$	NSEL,R,LOC,Y,0
*GET,minnode1,NODE,0,NUM,MIN
*GET,UXdisp1,NODE,minnode1,U,X

NSEL,S,LOC,X,(2*N-1)*(2*H-L*cos(alfa))	$	NSEL,R,LOC,Y,0
*GET,minnode2,NODE,0,NUM,MIN
*GET,UXdisp2,NODE,minnode2,U,X

!!! Zjisteni posuvu ve smeru y !!!
NSEL,S,LOC,X,0	$	NSEL,R,LOC,Y,(2*N-1)*L*sin(alfa)	
*GET,minnode3,NODE,0,NUM,MIN
*GET,UYdisp1,NODE,minnode3,U,Y

NSEL,S,LOC,X,0	$	NSEL,R,LOC,Y,-L*sin(alfa)
*GET,minnode4,NODE,0,NUM,MIN
*GET,UYdisp2,NODE,minnode4,U,Y

!!! Vypocet Poissonova pomeru !!!
dX=-UXdisp1+UXdisp2
dY=UYdisp1

X0=(2*H-L*cos(alfa))*2*N
Y0=2*N*L*sin(alfa)

epsX=dX/X0
epsY=dY/Y0

nuCALC=-epsX/epsY			! hodnota vysledneho Poissonova pomeru [-]

!!! Urceni plochy bunek !!!
S=N*2*(2*H-L*cos(alfa))*TH

!!! Vypocet E !!!
sigma=Fappl/S
Ecalc=abs(sigma/epsY)		! hodnota vysledneho pomerneho modulu pruznosti v tahu [-]



